13. DAX: Data Analysis Expressions

13.5 Base Measures for the Quick-Commerce Model

By Ravindra Bagale · Last updated: 25 September 2026

Create these first; later measures reuse them. Reusing measures ("measure branching") keeps your model consistent and easy to maintain. Remember the grain (एका ओळीचा नेमका अर्थ) from Module 1.7: one row per order line, and cancelled orders have Amount = 0.

Total Sales = SUM(Orders[Amount])                       -- net value after discount

Total Orders = DISTINCTCOUNT(Orders[Order ID])

Delivered Orders = CALCULATE([Total Orders], Orders[Order Status] = "Delivered")

Cancelled Orders = CALCULATE([Total Orders], Orders[Order Status] = "Cancelled")

Total Quantity = SUM(Orders[Quantity])

Total Discount = SUM(Orders[Discount])

Active Customers = DISTINCTCOUNT(Orders[Customer ID])

Format Total Sales and Total Discount as currency (₹) and ratio measures as percentage in Measure tools › Format.

Quick-commerce KPIs

AOV (Average Order Value) = DIVIDE([Total Sales], [Delivered Orders])

Cancellation Rate = DIVIDE([Cancelled Orders], [Total Orders])

-- Delivery time is an order-level value repeated on every line,
-- so first take one value per order, then average across orders
Avg Delivery Time (mins) =
AVERAGEX(
    VALUES(Orders[Order ID]),
    CALCULATE(MAX(Orders[Delivery Time Mins]))
)

% Orders Delivered Under 10 Mins =
DIVIDE(
    CALCULATE([Delivered Orders], Orders[Delivery Time Mins] <= 10),
    [Delivered Orders]
)

Orders per Dark Store =
DIVIDE([Total Orders], DISTINCTCOUNT(Orders[Store ID]))

Repeat Customer % =
DIVIDE(
    COUNTROWS(FILTER(VALUES(Customer[Customer ID]), [Total Orders] > 1)),
    [Active Customers]
)

Delivery Fee Revenue =
SUMX(
    VALUES(Orders[Order ID]),
    CALCULATE(MAX(Orders[Delivery Fee]))
)

Cost of Goods Sold =
CALCULATE(
    SUMX(Orders, Orders[Quantity] * RELATED(Product[Unit Cost])),
    Orders[Order Status] = "Delivered"
)

Gross Profit = [Total Sales] - [Cost of Goods Sold]

Gross Margin % = DIVIDE([Gross Profit], [Total Sales])

"Under 10 mins" here means 10 minutes or less (<= 10). Agree on the exact definition of every KPI with the business before building it.

Aata pudhe jaauya aggregation functions kade. Pan aadhi he base measures tumchya file madhe banvun theva.